Текст книги "Delphi. Трюки и эффекты"

Глава 12
Шифрование

• Основы криптографии

• Шифр простой подстановки

• Транспозиция

• Шифр Виженера и его варианты

• Шифр с автоключом

• Взлом

По той или иной причине часто бывает необходимо сообщить определенную информацию конкретному кругу людей так, чтобы она оставалась тайной для других. Возникает вполне очевидный вопрос: что для этого нужно сделать? Скорее всего, многие читатели в разные моменты времени и с различными целями пытались решить для себя задачу о секретной передаче. В результате выбиралось приемлемое решение, наверняка повторяющее изобретение одного из существующих способов скрытой передачи информации, история которого насчитывает не одну тысячу лет.

В отношении задачи о секретной передаче нетрудно прийти к выводу, что есть три способа ее реализации в компьютерных системах:

• создание абсолютно надежного канала связи, к которому есть доступ только у отправителя и адресата;

• использование общедоступного канала связи, но скрытие самого факта передачи информации;

• использование общедоступного канала связи с передачей по нему нужной информации, определенным образом преобразованной так, что восстановить ее может только адресат.

Что касается первого способа, то при современном уровне развития науки и техники сделать такой канал связи между удаленными абонентами для неоднократной передачи больших объемов информации практически нереально.

Второй способ является предметом изучения стеганографии. В область этой науки входит разработка средств и методов скрытия факта передачи сообщения.

Первые следы стеганографических методов теряются в глубокой древности. Например, известен такой способ скрытия письменного сообщения: голову раба брили, на коже головы писали сообщение и после отрастания волос раба отправляли к адресату.

Из детективных произведений хорошо известны различные способы тайнописи между строк обычного, незащищаемого текста: от молока до сложных химических реактивов с последующей обработкой.

Оттуда же известен метод «микроточки»: сообщение записывается с помощью современной техники на очень маленький носитель (микроточку), который пересылается с обычным письмом, например, под маркой или где-нибудь в другом, заранее обусловленном месте.

В настоящее время в связи с широким распространением компьютеров известно много тонких методов «запрятывания» защищаемых данных внутри больших объемов информации, хранящейся на компьютере.

Третий способ является предметом изучения криптографии. В ее область входит разработка методов преобразования (шифрования) информации с целью защиты от незаконных пользователей. Такие методы и способы преобразования информации называются шифрами.

12.1. Основы криптографии

Американский математик Клод Шеннон написал работу «Теория связи в секретных системах», в которой он обобщил накопленный до него опыт разработки шифров. В этой работе указано на то, что даже в самых сложных шифрах в качестве типичных компонентов можно выделить шифры замены, шифры перестановки или и х сочетание.

Для начала рассмотрим эти шифры, а позжереализуем их. Начнем, пожалуй, с шифра замены как с самого простого и наиболее популярного. Примерами самых распространенных из известных шифров замены могут служить шифр Цезаря, «цифирная азбука» Петра Великого и «пляшущие человечки» А. Конан Дойла. Из самого названия видно, что шифр замены осуществляет преобразование заменой букв или других «частей» открытого текста на аналогичные «части» шифрованного текста. Легко дать математическое описание шифра замены. Пусть X и Y – два алфавита (открытого и шифрованного текстов соответственно), состоящие из одинакового количества символов. Пусть также g: X → Y – взаимнооднозначное отображение X в Y. Тогда шифр замены действует так: открытый текст х1х2…хп преобразуется в шифрованный текст g(x1)g(x2)…g(xn).

Шифр перестановки, как видно из названия, осуществляет преобразование перестановки букв в открытом тексте. Примером одного из известных шифров перестановкой может служить шифр «Сцитала». Обычно открытый текст разбивается на отрезки равной длины, и каждый отрезок шифруется независимо. Пусть, например, длина отрезков равна п и g – взаимнооднозначное отображение множества {1,2…., п} в себя. Тогда шифр перестановки действует так: отрезок открытого текста х1х2…хп преобразуется в отрезок шифрованного текста xg(1)xg(2)…xg(n).

Важнейшим для развития криптографии был вывод К. Шеннона о существовании и единственности абсолютно стойкого шифра. Единственным таким шифром является какая-нибудь форма так называемой ленты однократного использования, в которой открытый текст «объединяется» с полностью случайным ключом такой же длины.

Этот вывод был доказан К. Шенноном с помощью разработанного им теоретико-информационного метода исследования шифров. Мы не будем здесь останавливаться на этом подробно, заинтересованному читателю рекомендуем изучить работу К. Шеннона.

Проясним для читателя один очень важный момент по поводу единственного абсолютно стойкого шифра. Чтобы шифр являлся таковым, должны выполняться три условия:

• полная случайность (равновероятность) ключа (это, в частности, означает, что ключ нельзя выработать с помощью какого-либо детерминированного устройства);

• равенство длины ключа и длины открытого текста;

• однократность использования ключа.

В случае нарушения хотя бы одного из этих условий шифр перестает быть абсолютно стойким и появляются принципиальные возможности для его вскрытия (хотя реализовать их может быть чрезвычайно сложно).

Но, оказывается, именно эти условия и делают абсолютно стойкий шифр очень дорогим и непрактичным. Прежде чем пользоваться таким шифром, мы должны обеспечить всех законных пользователей достаточным запасом случайных ключей и исключить возможность их повторного применения. А это сделать очень трудно и дорого.

В силу указанных причин абсолютно стойкие шифры применяются только в сетях связи с небольшим объемом передаваемой информации, обычно это сети для передачи особо важной государственной информации.

Теперь уже понятно, что чаще всего для защиты своей информации законные пользователи вынуждены применять не абсолютно стойкие шифры. Такие шифры могут быть вскрыты (по крайней мере, теоретически). Вопрос только в том, хватит ли у противника сил, средств и времени для разработки и реализации соответствующих алгоритмов. Обычно эту мысль выражают так: противник с неограниченными ресурсами может вскрыть любой не абсолютно стойкий шифр.

Как же должен действовать в этой ситуации законный пользователь, выбирая для себя шифр? Лучше всего, конечно, было бы доказать, что никакой противник не может вскрыть выбранный шифр, скажем, за десять лет и тем самым получить теоретическую оценку стойкости. К сожалению, математическая теория еще не дает нужных теорем – они относятся к нерешенной проблеме нижних оценок вычислительной сложности задач.

У пользователя остается единственный путь – получение практических оценок стойкости. Этот путь состоит из следующих этапов.

1. Понять и четко сформулировать, от какого противника мы собираемся защищать информацию. Необходимо уяснить, что именно противник знает или сможет узнать о системе шифра, а также какие силы и средства он сможет применить для его вскрытия.

2. Мысленно стать в положение противника и пытаться с его позиций атаковать шифр, то есть разрабатывать различные алгоритмы вскрытия шифра. При этом необходимо в максимальной мере обеспечить моделирование сил, средств и возможностей противника.

3. Наилучший из разработанных алгоритмов использовать для практической оценки стойкости шифра.

Полезно будет упомянуть о двух простейших методах вскрытия шифра: случайное угадывание ключа (он срабатывает с малой вероятностью, зато имеет небольшую сложность) и перебор всех подряд ключей вплоть до нахождения истинного (он срабатывает всегда, зато имеет очень большую сложность). Отметим также, что не всегда нужна атака на ключ: для некоторых шифров можно сразу, даже не зная ключа, восстанавливать открытый текст по шифрованному.

Теперь мы перейдем не только к столь необходимой теоретической части, но и к практической реализации различных криптосистем. Существует много их классификаций. Принципы классификации относятся не к качеству рассматриваемых криптосистем, а к присущим им свойствам.

12.2. Шифр простой подстановки

В шифре простой подстановки производится замена каждой буквы сообщения некоторым заранее определенным символом (обычно это также буква). В результате сообщение, имеющее видМ = т1т2 тЗт4…, где т1, тп2…. – последовательность букв, переходит в сообщение вида Е = е1е2еЗе4… = f(m1)f(m2)f(m3)f(m4)…, причем функция f(m) имеет обратную функцию g, для которой верно g(f(m)) = m, при всех возможных значениях т. В данном шифре ключом является просто перестановка алфавита (это верно в том случае, если буквы заменяются буквами). Например, подобная перестановка: ЛРЭИБПВЪДЁЗЩЙГХМЦАУОСЖТЯФКЕШНЫЬЧЮ. Она используется следующим образом:

• буква А открытого текста заменяется буквой Л;

• Б заменяется Р;

• В заменяется Э и т. д.

Как можно понять из определения, данный шифр является довольно простым. Перейдем к примеру, показывающему одну из возможных его реализаций. Для этого нам понадобится создать новое приложение, а на форму поместить следующие компоненты: по два компонента классов ТМето и TLabel с соответствующими именами mmDecryptMessage, mmEncryptMessage, IbDecryptMessage, IbEncryptMessage, три компонента класса TButton – btnEncryptMessage, btnDecpyptMessage, btnGenRearrangement, а также один компонент класса TValueListEditor – vleSubst. По умолчанию все перечисленные компоненты находятся на вкладке Standard, кроме компонента класса TValueListEditor, который расположен на вкладке Additional Когда вы закончите создание интерфейса программы, то у вас получится нечто подобное тому, что изображено на рис. 12.1.

Рис. 12.1. Интерфейс программы «Шифр простой подстановки»

Текстовый редактор mmDecryptMessage будет служить для ввода и отображения открытого текста нашего сообщения, mmEncryptMessage – для текста, преобразованного при помощи шифра. Редактор значений vleSubst мы будем использовать для задания перестановки алфавита, при помощи которой будет шифроваться и дешифроваться текст сообщения. Кнопка btnEncryptMessage будет отвечать за шифрование сообщения из текстового peflaKTopammDecryptMessage и помещение результата в mmEncryptMessage. Кнопка btnDecpyptMessage предназначена для противоположных действий. Последняя кнопка btnGenRearrangement будет служить для генерации случайной перестановки алфавита, чтобы не утруждать себя ее вводом вручную. Необходимо добавить обработчики событий Onclick для каждой из кнопок и обработчик события OnCreate для формы (он нужен для инициализации редактора значений vleSubst).

Теперь стоит оговориться, что программа будет шифровать и дешифровать только русский текст, отставляя неизменным все остальное. Далее рассмотрим исходный код нашей программы.

Первым делом нужно ввести необходимые типы для лучшего понимания написанного кода, а также следует соответствующим образом объявить класс формы. Как это сделать, показано в листинге 12.1.

Листинг 12.1. Объявление типов и класса нашей формы

type

TRusDstAlphabet = array [Char] of Char;

TfmSubstitution = class(TForm)

mmDecryptMessage: TMemo;

mmEncryptMessage: TMemo;

lbDecryptMessage: TLabel;

lbEncryptMessage: TLabel;

btnEncryptMessage: TButton;

btnDecpyptMessage: TButton;

btnGenRearrangement: TButton;

vleSubst: TValueListEditor;

procedure FormCreate(Sender: TObject);

procedure btnGenRearrangementClick(Sender: TObject);

procedure btnEncryptMessageClick(Sender: TObject);

procedure btnDecpyptMessageClick(Sender: TObject);

private

{ Private declarations }

RusDstAlphabet: TRusDstAlphabet;

procedure GenRearrangment;

function ValidateRearrangement: Boolean;

function UpCaseRus(Ch: Char): Char;

function LowCaseRus(Ch: Char): Char;

procedure RecalcAlphabet(nKey: Integer);

function EncryptDecryptString(strMsg: String): String;

public

{ Public declarations }

end;

Каждую задачу следует рассматривать детально и выделять необходимые подзадачи, решение которых позволит облегчить и упростить общее решение. Помимо ряда стандартных обработчиков событий, мы добавили несколько собственных методов для лучшей структуризации кода и повышения его читабельности, что является немаловажным фактором при разработке приложений. Рассмотрим каждый метод и поясним их работу.

В нашем приложении для удобства и простоты работы будет реализована возможность задания случайной автоматической перестановки. Первым рассматриваемым методом является функция, реализующая алгоритм генерации случайной перестановки заданной длины из букв русского алфавита. Принцип ее работы заключается в следующем. Сначала считается, что в перестановке нет ни единого символа, о чем свидетельствует установка всех элементов массива WasGen в значение False. Далее в цикле случайным образом генерируются буквы русского алфавита. На очередном шаге цикла буква генерируется до тех пор, пока она будет присутствовать среди уже сгенерированных. Как только такая буква получена, то соответствующий элемент массива WasGen устанавливается в значение True, которое свидетельствует о том, что буква больше не может быть сгенерирована. Мы также не забываем добавить ее в перестановку. Код, соответствующий данному описанию, приведен в листинге 12.2.

Листинг 12.2. Реализация метода генерации случайной перестановки

procedure TfmSubstitution.GenRearrangment;

var

Ch, c: char;

//нужен для определения, встречался ли символ ранее

WasGen: array [Char] of Boolean;

begin

//заполняем массив значением False

FillChar(WasGen, SizeOf(WasGen), False);

for Ch := 'А' to 'Я' do

begin

//генерируем случайный символ до тех пор, пока

//не будет получен еще не сгенерированный

repeat

c := Chr(Ord('А') + random(32));

until not WasGen[c];

//помечаем, что символ сгенерирован

WasGen[c] := True;

vleSubst.Values[Ch] := c;

end;

end;

В нашем приложении пользователь может сам задавать необходимую перестановку букв алфавита, поэтому стоит учесть тот факт, что он может ошибиться при ее вводе. Для решения данной проблемы реализуем функцию, которая будет отвечать на вопрос о том, является ли введенная перестановка корректной. Определимся с тем, каким критериям должна отвечать перестановка, чтобы считаться допустимой. Во-первых, в каждой ячейке ввода должна присутствовать лишь одна буква – ни больше, ни меньше. Во-вторых, каждая введенная буква обязана принадлежать множеству букв русского алфавита. И в-третьих, ни одна введенная буква не должна ни разу повторяться. Проверка первого критерия довольно проста. Для этого достаточно лишь проверить длину строки, введенной в каждой ячейке. Второй критерий также проверяется довольно простой конструкцией принадлежности заданному множеству. Третий критерий проверяется подобно тому, как в предыдущем реализованном методе проверялось, сгенерирована данная буква или нет. Следующий исходный код, представленный в листинге 12.3, показывает, как эта проверка осуществляется.

Листинг 12.3. Реализация метода проверки допустимости перестановки

function TfmSubstitution.ValidateRearrangement: Boolean;

var

i: Integer;

s: String;

Used: array [Char] of Boolean;

begin

Result := False;

FillChar(Used, SizeOf(Used), False);

for i := 1 to vleSubst.RowCount – 1 do

Begin

//символ единственный в строке?

s := vleSubst.Cells[1, i];

if (Length(s) <> 1) then

Exit;

//символ – буква русского языка?

s[1] := UpCaseRus(s[1]);

if not (s[1] in ['А'..’Я’]) then

Exit;

//уже встречался ранее?

if Used[s[1]] then Exit;

Used[s[1]] := True;

End;

Result := True;

end;

Далее мы реализуем две вспомогательные функции, которые позволят преобразовать буквы верхнего регистра к нижнему и наоборот. Их реализация немного специфична и основывается на используемой кодировке. Отдельная проверка буквы «Ё» производится на основании иного расположения в таблице кодировки, чем у остальных букв. Буквы русского алфавита верхнего регистра расположены начиная с «А» по порядку следования в алфавите, а сразу после них аналогично расположены буквы нижнего регистра. Этим объясняется увеличение кода буквы на фиксированное число. Реализация данных вспомогательных функций приведена в листинге 12.4.

Листинг 12.4. Вспомогательные функции преобразования регистра букв

function TfmSubstitution.UpCaseRus(Ch: Char): Char;

begin

if Ch = 'ё' then Ch := 'Е';

if Ch in ['а'..’я’] then Dec(Ch, 32);

Result := Ch;

end;

function TfmSubstitution.LowCaseRus(Ch: Char): Char;

begin

if Ch = 'Ё' then Ch := 'е';

if Ch in ['А'..’Я’] then Inc(Ch, 32);

Result := Ch;

end;

Теперь рассмотрим работу обработчика события формы OnCreate и обработчика события кнопки OnClick. Первый сначала инициализирует редактор значений полями, для которых будут задаваться данные. После того как все поля созданы, вызывается функция генерации случайной перестановки, которая, в свою очередь, заполняет все поля редактора значений необходимыми данными. Второй же обработчик только вызывает функцию генерации случайной перестановки. В листинге 12.5 приведен исходный код данных методов.

Листинг 12.5. Использование генерации случайной перестановки

procedure TfmSubstitution.FormCreate(Sender: TObject);

var

Ch: char;

begin

Randomize;

//инициализация редактора значений

for Ch := 'А' to 'Я' do

vleSubst.InsertRow(Ch, '', True);

//генерация случайной перестановки

GenRearrangment;

end;

procedure TfmSubstitution.btnGenRearrangementClick(Sender:

TObject);

begin

GenRearrangment;

end;

Следующим объектом нашего рассмотрения является функция предварительной подготовки алфавита преобразования для шифрования либо дешифрования сообщения. У метода RecalcAlphabet есть параметр пКеу, который в зависимости от своего значения показывает, что является ключом. Возможными значениями пКеу являются 0 и 1. Значение 0 указывает на то, что будет производиться шифрование сообщения и требуется поставить в соответствие буквам открытого текста буквы перестановки. Значение 1, напротив, указывает на то, что будет производиться дешифрование сообщения и требуется поставить в соответствие буквам перестановки буквы открытого текста. Для этого массив сопоставления символов изначально заполняется таким образом, чтобы каждый символ соответствовал самому себе. Это происходит в следующих строках метода:

for Ch := Low(RusDstAlphabet) to High(RusDstAlphabet) do RusDstAlphabet[Ch] := Ch;

После чего требуется подкорректировать данный массив таким образом, чтобы выполнялось требуемое соответствие. Для этого мы проходим по всем элементам редактора значений vleSubstn поправляем массив, указывая в качестве индекса элемента то, чему ставится соответствие, а в качестве значения элемента массива – то, что является соответствием.

for i := 1 to vleSubst.RowCount – 1 do

RusDstAlphabet[vleSubst.Cells[nKey, i][1]] :=

vleSubst.Cells[1 – nKey, i][1];

Редактор значений vleSubst предназначен для сопоставления букв верхнего регистра. Нам же требуется избавиться от различия между буквами верхнего и нижнего регистров. Для этого мы дополнительно производим следующие действия:

for i := 1 to vleSubst.RowCount – 1 do

RusDstAlphabet[LowCaseRus(vleSubst.Cells[nKey, i][1])] :=

LowCaseRus(vleSubst.Cells[1 – nKey, i][1]);

Мы рассмотрели работу данного метода по частям. Его полный код приведен в листинге 12.6. Как видите, все относительно просто. Здесь мы используем вспомогательную функцию LowCaseRus.

Листинг 12.6. Функция предварительной подготовки алфавита преобразования

procedure TfmSubstitution.RecalcAlphabet(nKey: Integer);

var

Ch: Char;

i: Integer;

begin

//предварительно все символы в алфавите шифрования

//соответствуют символам из незашифрованного алфавита

for Ch := Low(RusDstAlphabet) to High(RusDstAlphabet) do

RusDstAlphabet[Ch] := Ch;

//формируем алфавит отдельно для каждого из регистров букв

//здесь для верхнего

for i := 1 to vleSubst.RowCount – 1 do

RusDstAlphabet[vleSubst.Cells[nKey, i][1]] :=

vleSubst.Cells[1 – nKey, i][1];

//здесь для нижнего

for i := 1 to vleSubst.RowCount – 1 do

RusDstAlphabet[LowCaseRus(vleSubst.Cells[nKey, i][1])] :=

LowCaseRus(vleSubst.Cells[1 – nKey, i][1]);

end;

Еще одной вспомогательной функцией является функция преобразования строки символов с помощью алфавита преобразования в соответствии с указанной операцией. Работа ее довольно проста. В цикле осуществляется прямой проход по строке, и каждый символ, принадлежащий ей, заменяется соответствующим символом алфавита преобразования. В итоге мы получаем зашифрованную либо дешифрованную строку. Посмотреть исходный код данного метода можно в листинге 12.7.

Листинг 12.7. Преобразование строки при помощи массива сопоставления

function TfmSubstitution.EncryptDecryptString(strMsg: String):

String;

var

i: Integer;

begin

//преобразуем строку посимвольно

for i := 1 to Length(strMsg) do

strMsg[i] := RusDstAlphabet[strMsg[i]];

Result := strMsg;

end;

Теперь, используя все описанные функции, мы без труда можем зашифровать либо дешифровать сообщение. Например, чтобы зашифровать его, мы подготавливаем массив соответствия букв вызовом функции RecalcAlphabet с параметром 0. После чего для каждой строки открытого текста вызываем функцию EncryptDecryptString и в качестве результата получаем зашифрованную строку. Обработчики событий OnClick соответствующих кнопок шифруют либо дешифруют весь текст. Основная идея каждого из методов заключается в том, чтобы проверить корректность заданной перестановки, после чего производится предварительная подготовка алфавита сопоставления, и далее сообщение преобразуется (листинг 12.8).

Листинг 12.8. Шифрование/дешифрование сообщения

procedure TfmSubstitution.btnEncryptMessageClick(Sender:

TObject);

var

i: Integer;

begin

//проверяем корректность ввода перестановки

if ValidateRearrangement then

begin

//создаем алфавит преобразования открытого текста

RecalcAlphabet(0);

//предотвращаем перерисовку компонента до тех пор,

//пока не зашифруем все строки сообщения

mmEncryptMessage.Lines.BeginUpdate;

//очищаем текстовый редактор

mmEncryptMessage.Clear;

//шифруем открытый текст построчно

for i := 0 to mmDecryptMessage.Lines.Count – 1 do

mmEncryptMessage.Lines.Add(EncryptDecryptString

(mmDecryptMessage.Lines[i]));

//разрешаем перерисовку компонента

mmEncryptMessage.Lines.EndUpdate;

end

else

MessageDlg('Ошибка: символы подстановки заданы неверно',

mtError, [mbOk], 0);

end;

procedure TfmSubstitution.btnDecpyptMessageClick(Sender:

TObject);

var

i: Integer;

begin

//проверяем корректность ввода перестановки

if ValidateRearrangement then

begin

//создаем алфавит преобразования шифрованного текста

RecalcAlphabet(1);

mmDecryptMessage.Lines.BeginUpdate;

mmDecryptMessage.Clear;

//дешифруем шифрованный текст построчно

for i := 0 to mmEncryptMessage.Lines.Count – 1 do

mmDecryptMessage.Lines.Add(EncryptDecryptString

(mmEncryptMessage.Lines[i]));

mmDecryptMessage.Lines.EndUpdate;

end

else

MessageDlg('Ошибка: символы подстановки заданы неверно',

mtError, [mbOk], 0);

end;

В итоге мы получили вполне рабочий вариант приложения, способного без особого труда шифровать и дешифровать сообщения. На рис. 12.2 представлен результат работы данного приложения.

Рис. 12.2. Результат работы приложения «Шифр простой подстановки»