Текст книги "Delphi. Трюки и эффекты"

6.8. Работа с растровыми изображениями

Вы можете использовать точечный рисунок, чтобы запомнить изображение, а потом сохранить его в памяти, отобразить в другом месте окна вашего приложения или вообще в другом окне.

В некоторых случаях вы можете захотеть, чтобы ваше приложение запоминало и хранило изображение только временно. Например, когда вам необходимо промасштабировать его в каком-нибудь приложении для рисования. Для этого необходимо временно запомнить нормальное представление изображения и показать измененное. После того как пользователь опять выберет нормальное представление изображения, приложение будет обязано заменить промасштабированное изображение копией нормального, которое временно сохранено.

Чтобы временно запомнить изображение, вашему приложению необходимо вызвать функцию CreateCompatibleDC, чтобы создать контекст устройства памяти, совместимый с контекстом устройства экрана текущего окна. После этого вы создаете точечный рисунок с соответствующими атрибутами посредством вызова функции CreateCompatibleBitmap, а затем выбираете его в контексте устройства памяти уже известным вам образом.

После того как создан совместимый контекст устройства и выбран соответствующий точечный рисунок, вы можете запоминать изображение. Функция BitBlt получает изображение, а также копирует данные из исходного точечного рисунка и помещает их в точечный рисунок приемника. Однако два параметра функции не являются описателями точечных рисунков. Вместо этого функция получает два описателя контекстов устройств и копирует растровые данные из точечного рисунка, выбранного в исходном контексте устройства, в точечный рисунок, выбранный в целевом контексте устройства. В этом случае целевой контекст устройства является совместимым контекстом устройства. Когда копирование растровых данных завершается, изображение помещается в память. Чтобы восстановить изображение, вызовите повторно BitBlt, указав теперь в качестве источника совместимый контекст устройства и в качестве приемника контекст устройства экрана (принтера и т. д.).

Следующий пример демонстрирует, как можно получать изображения всего Рабочего стола, а также как полученное изображение можно масштабировать. В данном приложении мы будем обрабатывать три события формы: OnCreate, OnPaint, OnClose, а также одно событие кнопки Onclick.

Рассмотрим исходный код обработчика события OnCreate (листинг 6.5).

Листинг 6.5. Обработчик события OnCreate

procedure TfmCaptureImage.FormCreate(Sender: TObject);

begin

//создаем контекст устройства экрана

hdcScreen := CreateDC('DISPLAY', nil, nil, nil);

//создаем совместимый контекст устройства памяти

hdcCompatible := CreateCompatibleDC(hdcScreen);

bmpWidth := GetDeviceCaps(hdcScreen, HORZRES);

bmpHeight := GetDeviceCaps(hdcScreen, VERTRES);

//создаем совместимый точечный рисунок для hdcScreen

hbmScreen := CreateCompatibleBitmap(hdcScreen, bmpWidth,

bmpHeight);

if hbmScreen <> 0 then

hOldBitmap := SelectObject(hdcCompatible, hbmScreen)

else

hOldBitmap := 0;

Captured := False;

end;

Здесь происходит создание контекста устройства Рабочего стола посредством вызова функции CreateDC.

hdcScreen:= CreateDC('DISPLAY', nil, nil, nil);

После этого создается совместимый контекст устройства памяти для только что основанного контекста. Затем создается совместимый точечный рисунок.

bmpWidth := GetDeviceCaps(hdcScreen, HORZRES);

bmpHeight := GetDeviceCaps(hdcScreen, VERTRES);

//создаем совместимый точечный рисунок для hdcScreen

hbmScreen := CreateCompatibleBitmap(hdcScreen, bmpWidth, bmpHeight);

Если нам удалось создать совместимый точечный рисунок, то выбираем его в совместимом контексте устройства памяти. Еще мы вводим флаг, который указывает, сохранено ли в данный момент изображение. Все полученные данные сохраняются в полях формы, объявленных при описании ее класса.

hdcScreen, hdcCompatible: HDC;

hbmScreen, hOldBitmap: HBITMAP;

bmpWidth, bmpHeight: Integer;

Captured: LongBool;

Рассмотрим исходный код обработчика события OnPaint (листинг 6.6).

Листинг 6.6. Обработчик события OnPaint

procedure TfmCaptureImage.FormPaint(Sender: TObject);

var

hCurDC: HDC;

begin

if Captured then

begin

hCurDC := GetDC(Handle);

StretchBlt(hCurDC, 0, 0, Width, Height, hdcCompatible,

0, 0, bmpWidth, bmpHeight, SRCCOPY);

ReleaseDC(Handle, hCurDC);

end;

end;

Проверяем, есть ли изображение, которое нам необходимо показывать. Если да, то получаем контекст устройства нашего окна и масштабируем на него полученное изображение при помощи функции StretchBlt.

Перед закрытием формы мы должны освободить занятые нами ресурсы системы. Поэтому мы обрабатываем событие OnClose, исходный код обработчика которого приведен ниже (листинг 6.7).

Листинг 6.7. Обработчик события OnClose

procedure TfmCaptureImage.FormClose(Sender: TObject;

var Action: TCloseAction);

begin

//восстанавливаем точечный рисунок по умолчанию

if hOldBitmap <> 0 then

SelectObject(hdcCompatible, hOldBitmap);

//удаляем совместимый точечный рисунок

if hbmScreen <> 0 then

DeleteObject(hbmScreen);

//удаляем совместимый контекст устройства памяти

if hdcCompatible <> 0 then

DeleteDC(hdcCompatible);

//удаляем контекст устройства экрана

if hdcScreen <> 0 then

DeleteDC(hdcScreen);

end;

Нам осталось рассмотреть последний обработчик события Onclick кнопки, помещенной на нашу форму. В нем мы прячем окно, сохраняем изображение экрана и затем показываем наше окно (листинг 6.8).

Листинг 6.8. Сохранение захваченного изображения

procedure TfmCaptureImage.btnCaptureClick(Sender: TObject);

var

hdcForm: HDC;

begin

//прячем наше окно

Hide;

//сохраняем текущее изображение экрана

Captured := BitBlt(hdcCompatible, 0, 0, bmpWidth, bmpHeight,

hdcScreen, 0, 0, SRCCOPY);

//показываем наше окно

Show;

end;

В итоге мы создали довольно простое приложение, которое способно получать изображение всего Рабочего стола. Результат работы приложения приведен на рис. 6.3.

Рис. 6.3. Результат работы приложения «Захват изображения»

6.9. Альфа-смешивание

Здесь мы рассмотрим пример, иллюстрирующий, как осуществлять альфа-смешивание точечного рисунка. Мы создадим приложение, в котором окно делится на три горизонтальные области. Затем создается точечный рисунок с альфа-смешиванием в каждой из областей окна следующим образом:

• в верней области постоянная альфа = 50 %, но нет никакой исходной альфы;

• в средней области постоянная альфа = 100 % и исходная альфа = 0 %;

• в нижней области постоянная альфа = 75 % и исходная альфа переменная.

Добавим в описание нашей формы процедуру со следующим форматом заголовка:

procedure DrawAlphaBlend(hWnd: HWND; hdcwnd: HDC);

В самой процедуре объявим ряд переменных, которые нам понадобятся в процессе работы. Объявление приведено в листинге 6.9.

Листинг 6.9. Объявление переменных

var

hCurDC: HDC; //описатель контекста устройства,

//который мы создадим

bf: BLENDFUNCTION; //запись альфа-смешивания

hbmp: HBITMAP; //дескриптор точечного рисунка

bmi: BITMAPINFO; //заголовок точечного рисунка

pvBits: Pointer; //pointer to DIB section

ulWindowWidth, ulWindowHeight: ULONG; //ширина/высота

//клиентской области

ulBitmapWidth, ulBitmapHeight: ULONG; //ширина/высота

//точечного рисунка

rt: TRect; //используется для получения размера

//клиентской области

x,y: Integer; //циклические переменные

ubAlpha: UCHAR; //используется для создания

//прозрачного градиента

ubRed: UCHAR;

ubGreen: UCHAR;

ubBlue: UCHAR;

fAlphaFactor: Real;

r, g, b: UCHAR;

В самом начале процедуры осуществляем подготовку необходимых данных для альфа-смешивания. Данные содержат информацию о требуемых размерах, а также необходимые данные точечного рисунка. Рассмотрите листинг 6.10 с необходимыми комментариями.

Листинг 6.10. Подготовка необходимых данных

//получаем размеры клиентской области

Windows.GetClientRect(hWnd, rt);

//рассчитываем ширину и высоту клиентской области

ulWindowWidth := rt.right – rt.left;

ulWindowHeight := rt.bottom – rt.top;

if (ulWindowWidth = 0) or (ulWindowHeight = 0) then

Exit;

//делим окно на три горизонтальные области

ulWindowHeight := ulWindowHeight div 3;

//создаем контекст устройства для нашего точечного рисунка

hCurDC := CreateCompatibleDC(hdcwnd);

ZeroMemory(@bmi, sizeof(BITMAPINFO));

//Устанавливаем параметры точечного рисунка.

//Указываем ширину и высоту точечного рисунка для каждой

//из трех горизонтальных областей

//равными 60 % ширины и высоты главного окна.

//Смешивание в центре каждой из этих трех областей

with bmi.bmiHeader do

begin

biSize := sizeof(BITMAPINFOHEADER);

biWidth := ulWindowWidth – (ulWindowWidth div 5) * 2;

ulBitmapWidth := biWidth;

biHeight := ulWindowHeight – (ulWindowHeight div 5) * 2;

ulBitmapHeight := biHeight;

biPlanes := 1;

biBitCount := 32; //четыре восьмибитных составляющих

biCompression := BI_RGB;

biSizeImage := ulBitmapWidth * ulBitmapHeight * 4;

end;

//создаем DIB секцию и выбираем точечный рисунок в контексте

устройства

hbmp := CreateDIBSection(hCurDC, bmi, DIB_RGB_COLORS, pvBits,

0, 0);

SelectObject(hCurDC, hbmp);

Далее осуществляем описанное ранее альфа-смешивание для каждой из областей. Для первой области в точечном рисунке мы устанавливаем синий цвет точки. Задаем необходимые параметры альфа-смешивания и выполняем его (листинг 6.11).

Листинг 6.11. Альфа-смешивание верхней области

//в верхней области постоянная альфа = 50 %,

//но исходная альфа отсутствует

//цветовой формат для каждого пиксела 0xaarrggbb

//установим пикселы в синий цвет и альфу в ноль

for y := 0 to ulBitmapHeight – 1 do

for x := 0 to ulBitmapWidth – 1 do

PULONG(Integer(pvBits) +

(x + y * ulBitmapWidth) * sizeof(ULONG))^ := $000000ff;

bf.BlendOp := AC_SRC_OVER;

bf.BlendFlags := 0;

bf.AlphaFormat := 0; //игнорировать исходный альфа-канал

bf.SourceConstantAlpha := $7f; //половина $ff = 50 %

//прозрачности

if not Windows.AlphaBlend(hdcwnd, ulWindowWidth div 5,

ulWindowHeight div 5,

ulBitmapWidth, ulBitmapHeight,

hCurDC, 0, 0, ulBitmapWidth,

ulBitmapHeight, bf) then

begin

DeleteObject(hbmp);

DeleteDC(hCurDC);

Exit;

end;

По аналогии выполняем необходимые действия со средней областью. В центре точечного рисунка прозрачность отсутствует, поэтому там будет только указанный цвет. Установим в центре красный цвет, а остальную часть сделаем синей. Далее опять задаем необходимые параметры альфа-смешивания и выполняем его (листинг 6.12).

Листинг 6.12. Альфа-смешивание средней области

//в средней области постоянная альфа = 100 %, а исходная равна 0

for y := 0 to ulBitmapHeight – 1 do

for x := 0 to ulBitmapWidth – 1 do

if (x > Integer(ulBitmapWidth div 5)) and

(x < (ulBitmapWidth – ulBitmapWidth div 5)) and

(y > Integer(ulBitmapHeight div 5)) and

(y < (ulBitmapHeight – ulBitmapHeight div 5)) then

//в середине точечного рисунка альфа равна нулю,

//это означает, что каждый цветной компонент умножается на 0.

//Таким образом, после альфа-смешивания мы получим 0 * r,

//0x00 * g, 0x00 * b ($00000000)

//установим сейчас цвет пикселов в красный

PULONG(Integer(pvBits) +

(x + y * ulBitmapWidth) * eof(ULONG))^ := $00ff0000

else

//остальную часть точечного рисунка сделаем синей

PULONG(Integer(pvBits) +

(x + y * ulBitmapWidth) * sizeof(ULONG))^ := $000000ff;

bf.BlendOp := AC_SRC_OVER;

bf.BlendFlags := 0;

bf.AlphaFormat := AC_SRC_ALPHA; //используем исходную альфа

bf.SourceConstantAlpha := $ff; //непрозрачный

if not Windows.AlphaBlend(hdcwnd, ulWindowWidth div 5,

ulWindowHeight div 5 + ulWindowHeight, ulBitmapWidth,

ulBitmapHeight,

hCurDC, 0, 0, ulBitmapWidth, ulBitmapHeight, bf) then

begin

DeleteObject(hbmp);

DeleteDC(hCurDC);

Exit;

end;

В последней части происходит градиентное альфа-смешивание. Соответствующий код приведен в листинге 6.13.

Листинг 6.13. Альфа-смешивание нижней области

//нижняя область. Используем альфа = 75 % и переменную исходную альфу

//создаем градиентный эффект, используя исходную альфа

ubRed := $00;

ubGreen := $00;

ubBlue := $ff;

for y := 0 to ulBitmapHeight – 1 do

for x := 0 to ulBitmapWidth – 1 do

begin

ubAlpha := Trunc(x / ulBitmapWidth * 255) and $FF;

fAlphaFactor := ubAlpha / $ff;

r := (Round(ubRed * fAlphaFactor) * (1 shl 16)) and $FF;

g := (Round(ubGreen * fAlphaFactor) * (1 shl 8)) and $FF;

b := Round(ubBlue * fAlphaFactor) and $FF;

PULONG(Integer(pvBits) +

(x + y * ulBitmapWidth) * sizeof(ULONG))^ :=

(ubAlpha shl 24) or //0xaa000000

r or //0x00rr0000

g or //0x0000gg00

b; //0x000000bb

end;

bf.BlendOp := AC_SRC_OVER;

bf.BlendFlags := 0;

bf.AlphaFormat := AC_SRC_ALPHA;

bf.SourceConstantAlpha := $bf;

Windows.AlphaBlend(hdcwnd, ulWindowWidth div 5,

ulWindowHeight div 5 + 2 * ulWindowHeight,

ulBitmapWidth, ulBitmapHeight, hCurDC, 0, 0,

ulBitmapWidth, ulBitmapHeight, bf);

DeleteObject(hbmp);

DeleteDC(hCurDC);

Обработчик события OnPaint нашей формы использует написанную функцию каждый раз, когда требуется ее обновить. Для этого он получает контекст устройства нашей формы, производит заливку фона темно-синим цветом, а после вызывает функцию альфа-смешивания трех областей. Соответствующий исходный код приведен в листинге 6.14.

Листинг 6.14. Обработчик события OnPaint

procedure TfmAlphaBlending.FormPaint(Sender: TObject);

var

hCurDC: HDC;

hCurBrush, hOldBrush: HBRUSH;

begin

hCurDC := GetDC(Handle);

hCurBrush := CreateSolidBrush(RGB(0, 0, 64));

FillRect(hCurDC, Rect(0, 0, Width, Height), hCurBrush);

DrawAlphaBlend(Handle, hCurDC);

DeleteObject(hCurBrush);

ReleaseDC(Handle, hCurDC);

end;

Теперь осталось только взглянуть на результат нашей работы, запустив приложение (рис. 6.4).

Рис. 6.4. Результат работы приложения «Alpha-смешивание точечного рисунка»

На этом закончим рассмотрение работы с графикой в Delphi.

Глава 7
Системная информация и реестр Windows

• Системная информация

• Системное время

• Реестр

Возникала ли у вас необходимость программно определить текущее состояние компьютера или узнать какие-нибудь сведения об операционной системе? Можно только удивляться, как близко – практически «под носом» у программиста – находятся средства для получения системной информации и как сложно о них узнать. Речь идет о средствах, которые всегда доступны при программировании для Windows – функции Windows API.

В данной главе мы рассмотрим некоторые способы, при помощи которых можно «добыть» информацию, касающуюся операционной системы. Это может пригодиться, например, если вы используете в своих приложениях возможности, отличающиеся в различных платформах Windows. Но и не только в этих случаях.

Рассмотренные в данной главе функции Windows API являются самыми обычными во всех смыслах этого слова. Просто они часто упоминаются вскользь либо вообще не упоминаются в книгах для программирования в таких средах, как Borland Delphi.

В примерах представленной вашему вниманию главы, кроме получения информации о самой Windows, некотором оборудовании компьютера, также рассмотрена работа с системным реестром Windows – этакой базой данных, в которой хранится много всего полезного и не очень: от параметров ОС и настроек приложений до сведений о работе компьютера в реальном времени. Правда, по определенным причинам последние сведения хранятся не в реальных, а в виртуальных ключах реестра. Но обо всем по порядку.

7.1. Системная информация

Начнем с несложных примеров, позволяющих получить информацию об операционной системе, установленном на компьютере оборудовании и такие сведения реального времени, как загрузка памяти компьютера, состояние питания и т. д.

Получение сведений об операционной системе хотя и не является повседневной необходимостью, но все же в некоторых специфичных случаях может пригодиться. Например, когда ваша программа ведет себя по-разному при разных установленных обновлениях Windows. Либо когда вы самостоятельно пишете инсталлятор, который способен устанавливать версии программы, скомпилированные для Windows Me (95, 98) или Windows NT (2000, ХР).

Одним из способов узнать версию Windows является использование API-функции GetVersionEx. Она принимает в качестве параметра структуру OSVERSIONINFO (или OSVERSIONINFOEX, но об этом позже), заполняет поля этой структуры и в случае удачи возвращает ненулевое значение.

Объявление ANSI-версии структуры OSVERSIONINFO в библиотеке Delphi 7 выглядит следующим образом:

OSVERSIONINFOA = record

dwOSVersionInfoSize: DWORD; //Размер структуры

dwMajorVersion: DWORD; //Старшая часть версии ОС Windows

dwMinorVersion: DWORD; //Младшая часть версии

dwBuildNumber: DWORD; //Номер сборки операционной системы

dwPlatformId: DWORD; //Идентификатор платформы Windows

szCSDVersion: array[0..127] of AnsiChar; //Дополнительные

//сведения, например, установленный пакет обновлений

end;

Не будем вдаваться в подробное описание возможных значений полей этой структуры: практически все будет ясно из приведенного далее примера. Напомним лишь, чтобы вы не забывали заполнять поле dwOSVersionInf oSize перед вызовом функции GetVersionEx.

Итак, пример обработки данных, помещаемых в структуру OSVERSIONINFO, приведен в листинге 7.1. При загрузке формы элемент управления ListView с именем lvwVerlnf о заполняется сведениями о версии системы, представленными в читабельной форме.

Листинг 7.1. Получение и отображение сведений о Windows

procedure TForm1.FormCreate(Sender: TObject);

var

info: OSVERSIONINFO;

item: TListItem;

begin

//Получаем информацию о версии ОС

info.dwOSVersionInfoSize := SizeOf(info);

GetVersionEx(info);

//Заполняем список информацией о ОС

//..версия ОС

item := lvwVerInfo.Items.Add();

item.Caption := 'Версия системы';

item.SubItems.Insert(0, IntToStr(Integer(info.dwMajorVersion)) +

'.' + IntToStr(Integer(info.dwMinorVersion)));

//..номер сборки

item := lvwVerInfo.Items.Add();

item.Caption := 'Сборка';

item.SubItems.Insert(0, IntToStr(Integer(info.dwBuildNumber)));

//..платформа

item := lvwVerInfo.Items.Add();

item.Caption := 'Платформа';

case info.dwPlatformId of

VER_PLATFORM_WIN32s:

//Эмуляция Win32 или Win16

item.SubItems.Insert(0, 'Win16');

VER_PLATFORM_WIN32_WINDOWS:

//"Классическая" Win32: 95, 98 или Me

item.SubItems.Insert(0, 'Win32');

VER_PLATFORM_WIN32_NT:

//Ядро NT

item.SubItems.Insert(0, 'WinNT');

end;

//..дополнительная информация (например, пакет обновлений)

item := lvwVerInfo.Items.Add();

item.Caption := 'Дополнительные сведения';

item.SubItems.Insert(0, info.szCSDVersion);

end;

Возможный результат работы программы (для Windows ХР SP1) приводится на рис. 7.1.

Рис. 7.1. Информация о версии Windows

Теперь снова обратимся к функции GetVersionEx, точнее говоря, к структуре OSVERSIONINFOEX, которая может также передаваться в качестве параметра в функцию. К сожалению, в библиотеке Delphi 7 эта структура не объявлена. Но это можно сделать самостоятельно:

OSVERSIONINFOEX = record

dwOSVersionInfoSize: DWORD;

dwMajorVersion: DWORD;

dwMinorVersion: DWORD;

dwBuildNumber: DWORD;

dwPlatformId: DWORD;

szCSDVersion: array[0..127] of AnsiChar;

//Поля, которых нет в OSVERSIONINFO

wServicePackMajor: WORD; //Старшая цифра версии пакета

//обновлений

wServicePackMinor: WORD; //Младшая цифра версии пакета

//обновлений

wSuiteMask: WORD; //Комплектация системы

wProductType: BYTE; //Дополнительная информации об ОС

wReserved: BYTE;

end;

Дополнительные (по сравнению с OS VERS ION INFO) поля структуры может заполнить ОС Windows NT 4.0 SP6 и более поздние версии Windows NT (в том числе 2000 и ХР). Значения дополнительных полей структуры OSVERSIONINFOEX пояснены комментариями в объявлении структуры.

Значение поля wSuiteMask (является битовой маской) может быть составлено из значений следующих констант (увы, но их объявления также пришлось добавить самостоятельно).

VER_SUITE_BACKOFFICE = 4; //Установлена Microsoft Back Office

VER_SUITE_DATACENTER = 128;//Установлена Microsoft Data Center

VER_SUITE_ENTERPRISE = 2; //Установлена ОС Windows 2000

//Advanced Server

VER_SUITE_SMALLBUSINESS = 1; //Установлена Microsoft Small

//Business Server

VER_SUITE_SMALLBUSINESS_RESTRICTED = 32; //Установлена

//ограниченная версия Microsoft

//Small Business Server

VER_SUITE_TERMINAL = 16; //Установлены терминальные службы

VER_SUITE_PERSONAL = 512; //Персональная версия ОС (типичный

//набор функций меньше, чем в Professional)

Значение поля wProductType может быть одним из приведенных ниже (тип сетевой ОС и соответственно роль, которую компьютер с данной ОС может исполнять при подключении в сети):

VER_NT_WORKSTATION = 1; //Рабочая станция

VER_NT_DOMAIN_CONTROLLER = 2; //Контроллер домена

VER_NT_SERVER = 3; //Сервер

Чтобы можно было просто передавать в функцию GetVersionEx ссылку на структуру OSVERSIONINFOEX, а не OSVERSIONINFO, перегрузим эту функцию следующим образом:

function GetVersionEx(var lpVersionInformation: OSVERSIONINFOEX): BOOL;

stdcall; external kernel32 name 'GetVersionExA';

Теперь определение полной информации о версии ОС для случая Windows на платформе NT (выше NT 4.0 SP6) может выглядеть следующим образом (листинг 7.2) (часть, одинаковая с листингом 7.1, опущена).

Листинг 7.2. Определение версии ОС (NT, 2000, ХР)

procedure TForm1.FormCreate(Sender: TObject);

var

info: OSVERSIONINFOEX;

item: TListItem;

suite, additional: String;

begin

//Получаем информацию о версии ОС

info.dwOSVersionInfoSize := SizeOf(info);

GetVersionEx(info);

//Заполняем список информацией об ОС

//…

//..версия о пакете обновлений

item := lvwVerInfo.Items.Add();

item.Caption := 'Версия ServicePack';

item.SubItems.Insert

(0, IntToStr(Integer(info.wServicePackMajor)) + '.' +

IntToStr(Integer(info.wServicePackMinor)));

//..комплекация ОС

suite := '';

if info.wSuiteMask and VER_SUITE_BACKOFFICE <> 0 then

suite := suite + '[Установлен Back Office] ';

if info.wSuiteMask and VER_SUITE_DATACENTER <> 0 then

suite := suite + '[Microsoft Data Center] ';

if info.wSuiteMask and VER_SUITE_ENTERPRISE <> 0 then

suite := suite + '[Windows 2000 Advanced Server] ';

if info.wSuiteMask and VER_SUITE_SMALLBUSINESS <> 0 then

suite := suite + '[Small Business Server] ';

if info.wSuiteMask and VER_SUITE_SMALLBUSINESS_RESTRICTED <> 0

then

suite := suite + '[Small Business Server, ограниченная версия] ';

if info.wSuiteMask and VER_SUITE_TERMINAL <> 0 then

suite := suite + '[Terminal Service] ';

if info.wSuiteMask and VER_SUITE_PERSONAL <> 0 then

suite := suite + '[Workstation Personal (не Professional)] ';

item := lvwVerInfo.Items.Add();

item.Caption := 'Комплектация';

item.SubItems.Add(suite);

//..дополнительные сведения

additional := '';

if info.wProductType and VER_NT_WORKSTATION <> 0 then

additional := additional + '[Рабочая станция] ';

if info.wProductType and VER_NT_DOMAIN_CONTROLLER <> 0 then

additional := additional + '[Контроллер домена] ';

if info.wProductType and VER_NT_SERVER <> 0 then

additional := additional + '[Сервер] ';

item := lvwVerInfo.Items.Add();

item.Caption := 'Дополнительно';

item.SubItems.Add(additional);

end;